// gamma calebration plaque
// ŠJohn M. Dlugosz, http://www.dlugosz.com/POV/Gamma/


global_settings {
   assumed_gamma 1.0  /* "For new scenes, you should use an
      assumed gamma value of 1.0 as this models 
      how light appears in the real world more realistically." */
   }

#include "colors.inc"
#include "textures.inc"

camera {
   location  <0, 3,-15>
   direction <0, 0,  1.5>
   up        <0, 1,  0>
   right   <4/3, 0,  0>
   look_at   <0, 3, 0>
}

light_source {<10, 20, -30> color 2*White}

sky_sphere { pigment { Blue } }

// Floor
plane { y, 0
   pigment {NeonBlue}
   finish {ambient 0.15 diffuse 0.8}
}

#local targetsize= <10,6,0.5>;
#local W1= 1;  //feature width base


#macro GrayBar (index, gamma)
   #local barwid= (targetsize.x-W1*2)/BarCount;
   box {  <0,targetsize.y/2,0>, <barwid, targetsize.y, targetsize.z>  translate x*(W1+barwid*(index-1))
      texture {
         pigment { White * (pow(0.5, (1/gamma))) }
         }
      }
   #end


union {
   box {  //black
      0, <W1, targetsize.y, targetsize.z>
      texture {
         pigment { Black }
         }
      }
   box {  //white
      <targetsize.x-W1, 0,0>, targetsize
      texture {
         pigment { White }
         }
      }
   box {  // bottom half -- checker pattern
      <W1,0,0>, <targetsize.x-W1, targetsize.y/2, targetsize.z>
      texture {
         pigment { checker  Gray25,  Gray75 }
         scale 0.08
         }
      }
   // top half -- different gray values
   #declare BarCount= 8;
   GrayBar (1, 0.4)
   GrayBar (2, 0.8)
   GrayBar (3, 1.0)
   GrayBar (4, 1.4)
   GrayBar (5, 1.6)
   GrayBar (6, 1.8)
   GrayBar (7, 2.0)
   GrayBar (8, 2.2)
   
   translate -targetsize.x/2*x
   }